Printer function test after distribution update

Print as Print Can

Article from Issue 187/2016
Author(s):

Cautious administrators will want to make sure a Linux installation is still working as intended after an update. A simple test suite offers that assurance.

If you are an administrator and regularly thrill your flock of users with Linux distribution updates, you will want to avoid annoying complaints and problems by actually testing the functionality up front. As an example of a potential approach, this article looks at how to check a shared printer.

When you type "Printers" into the Ubuntu search field, you are taken to a dialog displaying all the connected printers (Figure 1). You could select a printer manually at this point and talk it into printing a test page. But, how can you use an automated test to handle this task – and other tests for similar situations?

Figure 1: All the installed printers in the Printers dialog on Ubuntu.

First Attempt

The Linux Desktop Testing Project (LDTP) [1] is dedicated to testing GUIs on all kinds of platforms, including Windows. LDTP relies on the accessibility features of window managers like Gnome or KDE and even lets you control them remotely. The project, however, does not look very healthy, and the documentation is gappy. Even following a request I sent to the developers, I was unable to talk the GUI into responding appropriately, because either the LDTP daemon crashed or did something unexpected compared with what the sparse documentation advertised. Definitely a good idea, but maintenance needs to be improved if the project is to be of any practical use.

At My Command

The command-line tools lpstat, lpr, and lpq helped me out of this hole; they list all the configured printers, print a document, and let you visualize the print queue. When bundled into a Perl script, these commands find the standard printer, tell it to print a test document, and check whether the job first appears in the queue and then disappears again when done. If the output from the typical Perl TAP (Test Anything Protocol) is then ok rather than not ok in all disciplines, the printer has passed the test and the newly installed distribution is functional – at least, in terms of the printing environment. Figure 2 shows the output from a successful printer test.

Figure 2: The test suite finds the default printer, prints a document, and then checks the queue.

The test script in Listing 1 [2] uses Perl's backquote mechanism to call the command-line tools and saves the output in variables for checking later on via regular expressions. Perl's Test::More test module exports the ok and is functions, which check return values and compare actual and expected results. ok and is also sound the alarm if an unexpected event occurs.

Listing 1

lptest-default

01 #!/usr/local/bin/perl -w
02 use strict;
03 use Test::More;
04 use Getopt::Long;
05 use Path::Tiny;
06
07 my $realprint = 1;
08 GetOptions( "realprint!" => \$realprint );
09
10 my $lpstat = "lpstat";
11 my $lpr    = "lpr";
12 my $lpq    = "lpq";
13
14 my( $default_printer ) =
15   ( `$lpstat -d` =~ /: (.*)/ );
16
17 if( !defined $default_printer ) {
18     die "Cannot find default printer";
19 }
20
21 ok 1,
22   "found default printer $default_printer";
23
24 SKIP: {
25     if( !$realprint ) {
26         skip "printing disabled", 1;
27     }
28
29     ok !lpq_busy(), "lpq empty";
30
31     my $temp = Path::Tiny->tempfile;
32     $temp->spew( "This is a test." );
33
34     my $rc = system $lpr, "-P",
35         $default_printer, $temp->absolute;
36     is $rc, 0, "printing with $lpr";
37
38     ok lpq_busy(), "lpq busy";
39
40     while( lpq_busy() ) {
41         sleep 1;
42     }
43
44     ok !lpq_busy(), "lpq empty";
45 }
46
47 done_testing;
48
49 sub lpq_busy {
50     my $queue = `$lpq`;
51
52     return $queue =~ /active/;
53 }

The ok() function checks whether the first parameter passed in contains a true value, and is() compares the value it sees (first parameter) with the expected value (second parameter).

Run at the command line, lpstat in Figure 3 tells me that a multifunctional printer by the name of MFC7420 is configured on my Ubuntu installation, as well as an array of label printers by Dymo, which I introduced three months back in this Perl column [3]. Because the distribution test only tests the function of the default printer, the test script in Listing 1 calls lpstat -d, grabs the output showing the default printer, and checks whether the output contains at least one line with a colon character.

Figure 3: The lpstat command lists all the configured printers.

Default Printer

If lpstat finds a default printer, this is a good sign that the newly installed distribution is working properly. For further tests, the script actually has to send a print job. If you don't want to waste paper on printing, you will want to call lptest-default with the --norealprint option, which tells the test script to skip the section marked SKIP at line 24. In this case, the output shows the restricted test coverage:

$ ./lptest-default --norealprint
ok 1 - found default printer MFC7420
ok 2 # skip printing disabled
1..2

The GetOptions() function called in line 8 defines the --realprint command-line parameter for this purpose; line 7 sets it to 1 by default, that is, it prints for real unless you say otherwise.

The exclamation mark at the end of the realprint! option tells GetOptions() that the negation with --norealprint at the command line sets the $realprint variable to a false value in the script, thus disabling actual printing.

Buy this article as PDF

Express-Checkout as PDF
Price $2.95
(incl. VAT)

Buy Linux Magazine

SINGLE ISSUES
 
SUBSCRIPTIONS
 
TABLET & SMARTPHONE APPS
Get it on Google Play

US / Canada

Get it on Google Play

UK / Australia

Related content

  • Command Line – CUPS

    Using the Common Unix Printing System, you can configure and manage your printer from the command line.

  • AirPrint in Linux

    If your home network includes a Linux machine, you have access to everything you need to share your printers on the network as AirPrint-enabled devices.

  • Bluetooth Printing

    Even if your printer vendor doesn’t advertise Linux Bluetooth support, there are a few tools that may help you set up your Linux system for Bluetooth printing.

  • Ask Klaus!

    Klaus Knopper answers your Linux questions.

  • Ask Klaus!
comments powered by Disqus

Direct Download

Read full article as PDF:

Price $2.95

News

njobs Europe
What:
Where:
Country:
Njobs Netherlands Njobs Deutschland Njobs United Kingdom Njobs Italia Njobs France Njobs Espana Njobs Poland
Njobs Austria Njobs Denmark Njobs Belgium Njobs Czech Republic Njobs Mexico Njobs India Njobs Colombia